Rule

A "Rules Engine" allows various types of business rules to be written in a text format and easily applied to the system "on the fly" – without even logging out or shutting it down.  USAS-R comes with its own set of required business rules, as well as a number of optional business rules that the district may enable or disable as they desire.  Customized rules can also be written for each district, either by district personnel with the appropriate access to do so, or with help from their ITC or the SSDT.  A few examples of using customized business rules are custom validations, sending email or Twitter notifications, or even updating fields based on certain criteria.  These can also be used in conjunction with Custom Fields 

Create

1. From the System menu select 'Rules'
2. Click on

3. Enter in required rule information

   Check the enabled box if the user wants it to be in affect the next time the rulesets are activated
4. Click on  to ensure rule is correct
5. Click on  to create the rule, click on  to not create the rule.

Activate

Rules do not take affect as soon as they are saved.  In order to make a new or changed rule take affect, the user would click on .  This will reload all of the enabled rulesets and they will become effective immediately.

Search

The Rules grid allows the user to search for existing Rules on the system by clicking in the filter row in the grid columns and entering in the desired information. Click on any row of the search results to see a summary view of the record.  The Advanced Search can be utilized by clicking on the   in the upper right side of the grid.

Edit

The options listed will depend if the rule is bundled and/or mandatory. If the rule is bundled and mandatory a user will only be able to view it. If the rule is bundled and not mandatory the user will be able to view or disable it. If the rule is not bundled then the user will be able to edit, delete or disable it. 

Click on the   in the grid beside the Rule to edit the record.

Disable Rule

A rule may be disabled if it is not mandatory.

1. From the System menu select 'Rules'
2. Search for desired Rule
3. Click on
4. Uncheck the
5. Click on and close the pop up window
6. Click on in order for the change to go into affect

Enable Rule

A disabled rule may be enabled at any time.  

1. From the System menu select 'Rules'
2. Search for desired Rule
3. Click on
4. Check the 
5. Click on and close the pop up window
6. Click on in order for the change to go into affect

Delete

Click on the    in the grid beside the desired rule.  A confirmation box will appear and you will be asked to confirm that you really do want to delete this rule. A rule may be deleted if it is not bundled.

Mandatory Rules

The following rules come with the software (bundled) and are mandatory in order to use the software.  They will be enabled automatically when the data is imported.  Mandatory rules cannot be disabled.

Bundled Rules that are not Mandatory

The following rules come with the software but are not mandatory in order to use the software.   

Custom Rules

Customized rules can also be written for each district, either by district personnel with the appropriate access to do so, or with help from their ITC or the SSDT.  A few examples of using customized business rules are custom validations, sending email or Twitter notifications, or even updating fields based on certain criteria.  These can also be used in conjunction with Custom Fields. 

A few things worth mentioning with regards to rules. 

• You need to make sure the name of the rule is unique. 
• You'll also want to validate the rule to make sure there are no errors. 
• Finally, once you've successfully saved your rule, you need to make sure to click the Activate button from the rule grid for the rule to take effect.

The following are custom rules that can be created:

Require a deliver to address when creating a requisition 

Name: org.districtname.RequisitionDeliveryAddressRequired

Description: Prevent posting Requisition without a Delivery Address

package org.districtName.Requistion.DeliveryAddressRequired;
dialect  "mvel"

import function org.ssdt_ohio.modules.rules.RulesHelper.*
import org.ssdt_ohio.model.ModelInformation;
import org.ssdt_ohio.model.ModelState;
import org.ssdt_ohio.model.events.*;
import org.ssdt_ohio.usas.model.requisition.Requisition;
import org.ssdt_ohio.usas.model.vendor.Vendor;

rule "requisition delivery address is required" 

	when
	    CreateObjectEvent() or UpdateObjectEvent()
    	ModelInformation(state != ModelState.IMPORTING, primary)
	    $requisition : Requisition(deliveryAddress.isEmpty())

    then
    	error(kcontext, "Requisition cannot be saved without a delivery address")

end

Require a vendor when creating a requisition

Name: org.districtname.RequisitionVendorRequired

Description: Prevent posting Requisition without a Vendor

package org.districtName.Requisition.VendorRequired;
dialect  "mvel"

import function org.ssdt_ohio.modules.rules.RulesHelper.*
import org.ssdt_ohio.model.ModelInformation;
import org.ssdt_ohio.model.ModelState;
import org.ssdt_ohio.model.events.*;
import org.ssdt_ohio.usas.model.requisition.Requisition;
import org.ssdt_ohio.usas.model.vendor.Vendor;

rule "requisition vendor is required" 

	when
	    CreateObjectEvent() or UpdateObjectEvent()
    	ModelInformation(state != ModelState.IMPORTING, primary)
	    $requisition : Requisition(getVendor() == null)

    then
    	error(kcontext, "Requisition cannot be saved without a vendor")

end

Require that an account code be entered for each requisition line item when creating requisition

Name: org.districtname.RequisitionWithoutAccount 

Description: Prevent requisition from being created without account code 

package org.ssdt_ohio.usas.model.requisition;
dialect "mvel"

import function org.ssdt_ohio.modules.rules.RulesHelper.*
import org.ssdt_ohio.model.events.*
import org.ssdt_ohio.model.ModelInformation
import org.ssdt_ohio.model.ModelState
import org.ssdt_ohio.usas.model.requisition.*
import org.ssdt_ohio.usas.model.accountChange.AccountChangeUpdateRules

rule "require accounts on requisitions"

	when
		CreateObjectEvent() or UpdateObjectEvent()
		ModelInformation(state != ModelState.IMPORTING, primary)
		not AccountChangeUpdateRules()
		$req : Requisition()
		RequisitionCharge(account == null) from $req.charges

	then
		error(kcontext, "Expenditure Account is required")

end

Prevent Requisition from being created when the attention to field is blank

Name: org.districtname.RequisitionWithoutAttentionTo 
Description: Prevent requisition from being created when attention to is blank

package org.districtName.RequisitionAttentionTo;
dialect  "mvel"

import function org.ssdt_ohio.modules.rules.RulesHelper.*
import org.ssdt_ohio.model.ModelInformation;
import org.ssdt_ohio.model.ModelState;
import org.ssdt_ohio.model.events.*;
import org.ssdt_ohio.usas.model.requisition.Requisition;
import org.ssdt_ohio.usas.model.vendor.Vendor;

rule "requisition vendor is required" 

	when
    	CreateObjectEvent() or UpdateObjectEvent()
    	ModelInformation(state != ModelState.IMPORTING, primary)
   		$requisition : Requisition(attention == null)

    then
    	error(kcontext, "Requisition must have valid attention field")

end

Prevent Requisition from being saved or updated when any of the item descriptions are null or are an empty string

Name: org.districtname.RequisitionItemsWithNoDescription

Description: Prevent requisition from being saved or updated when any of the item descriptions are null or are an empty string

package org.districtName.Requisition
dialect "mvel"

import function org.ssdt_ohio.modules.rules.RulesHelper.*
import org.ssdt_ohio.model.events.*
import org.ssdt_ohio.model.ModelInformation
import org.ssdt_ohio.model.ModelState
import org.ssdt_ohio.usas.model.requisition.*


rule "Requisition Items Must Have A Description"

	when
		$event : RepositoryModificationEvent(isCreate() || isUpdate())
		ModelInformation(state != ModelState.IMPORTING, primary)
		$requisition : Requisition() from $event.target
		$item : RequisitionItem(description == null || description.trim().length() == 0) from $requisition.getItems()

	then
		error(kcontext, "Requitistion item number: " + $item.lineNumber + ", units: " + $item.units +
		", quantity: " + $item.quantity + ", unit price: " + $item.unitPrice +
		" has no description from requisition: " + $requisition.description)

end

Require an amount on a requisition line item.

Name: Requisition Items must have an Amount

Description: Prevent requisition from being saved or updated when any of the items are null or are empty

package org.ssdt_ohio.usas.model.requisition;
dialect  "mvel"
//ssdt: mandatory=false, enabled=true, description=Error: requisition item amount must be specified
import function org.ssdt_ohio.modules.rules.RulesHelper.*
import org.ssdt_ohio.model.ModelInformation
import org.ssdt_ohio.model.ModelState
import org.ssdt_ohio.model.events.*
import org.ssdt_ohio.usas.model.account.ExpenditureAccount
import org.ssdt_ohio.usas.model.account.ExpenditureCode
rule "RequisitionItemAmounts"
    when
        ModelInformation(state != ModelState.IMPORTING, primary)
        CreateObjectEvent() or UpdateObjectEvent()
        $requisition: Requisition()
        $item : RequisitionItem(amount == null || amount == 0) from $requisition.items
    then
        error(kcontext, "Item amount required for item: " + $item.lineNumber)
end

Require an amount on a Receipt item

Name: org.districtname.ReceiptItemsWithoutAmount

Description: Prevent receipt from being saved or updated when a receipt item amount is empty

package org.ssdt_ohio.usas.model.receipt;
dialect  "mvel"
//ssdt: mandatory=false, enabled=true, description=Error: receipt item amount must be specified

import function org.ssdt_ohio.modules.rules.RulesHelper.*
import org.ssdt_ohio.model.ModelInformation
import org.ssdt_ohio.model.ModelState
import org.ssdt_ohio.model.events.*
import org.ssdt_ohio.usas.model.account.RevenueAccount
import org.ssdt_ohio.usas.model.account.RevenueCode

rule "ReceiptItemAmounts"
    when
        ModelInformation(state != ModelState.IMPORTING, primary)
        CreateObjectEvent() or UpdateObjectEvent()
        $receipt : Receipt()
        $item : ReceiptItem(amount == null || amount == 0) from $receipt.items

    then
        error(kcontext, "Item amount required for item: " + $item.lineNumber)
end

More Information